« Tcl: Iterazioni: comandi continue e break • Appunti di Tcl/Tk • Tcl: Creazione di nuovi comandi: comandi proc e return »

Tcl

Iterazioni

una implementazione Tcl del comando do

In Tcl puro non esiste l'equivalente dell'istruzione do ... while del C. Tuttavia data la natura estendibile di Tcl, è possibile implementarsela! Tcl è uno dei pochi linguaggi che permette di implementare nuove strutture di controllo in modo semplice. Questo è dovuto al fatto che in Tcl ci sono solo comandi, quindi anche le strutture di controllo sono dei comandi, ovvero possono essere definite come comandi o procedure, con l'aiuto di qualche altro comando specializzato.

Per esemplificare riportiamo di seguito l'implementazione di un comando do con la seguente semplice sintassi, simile a quella di while(n):

while body test

#!/bin/sh
# restart using tclsh \
exec tclsh8.4 "$0" "$@"

proc do {body test} {
  set code [catch {uplevel 1 $body} string]
  switch $code {
    0 {
      # TCL_OK
    }

    1 -
    2 {
      # TCL_ERROR, TCL_RETURN
      return -code $code $string
    }

    3 {
      # TCL_BREAK
      return
    }

    4 {
      # TCL_CONTINUE
    }
  }

  uplevel [list while $test $body]
}

Ecco uno spezzone di codice di test, che permette di giocare ad "indovina-un-numero":

# test:
# the guess-a-number game

set num [expr int(1+rand()*10)]
set tries 0

puts {Guess a number between [1-10].}
do {
  incr tries
  puts -nonewline "try #$tries: "
  flush stdout

  if {[gets stdin line]==-1 || [scan $line %d guess]!=1} {
    break
  }

  if {$guess==$num} {
    puts "You won with $tries tries."
    exit
  }
} {$tries<5}

puts "Game over. Number was $num."

Alcune osservazioni sull'implementazione di do:

• L'idea fondamentale è di utilizzare il comando while(n); dapprima si esegue il body una volta, poi si esegue il comando

  while $test $body
  

  che implementa per noi le eventuali successive iterazioni. Questo corrisponde alla semantica del do...while del C.
• Non si può eseguire il body o il test a livello della procedura do, in quanto a questo livello di stack non è accessibile il contesto delle variabili a cui il codice del body o del test tipicamente fa riferimento. Si usa pertando il comando uplevel(n) che permette di eseguire uno script in un diverso stack frame. Nel nostro caso occorre eseguire gli script body e test proprio nello stack frame precedente (di distanza 1 da quello corrente).
• Il primo parametro di uplevel indica il contesto delle variabili in cui eseguire lo script costituito dalla concatenazione degli argomenti successivi, e se omesso vale 1 (valore di default). Tuttavia se il primo argomento di uplevel inizia con una cifra oppure il carattere #, il valore di default va specificato pena un errore. Per questo motivo è stato specificato nel comando:

  uplevel 1 $body
  

  mentre non occorre specificarlo nel comando uplevel successivo in quanto il primo argomento è la stringa costante while che non inizia per cifra o per #.
• Il comando uplevel concatena i suoi argomenti come fa concat(n) e poi valuta lo script risultante nello stack frame voluto. Qualora gli argomenti di uplevel dopo l'eventuale indicazione del livello siano più di uno, occorre in generale utilizzare il comando list(n) per ottenere il corretto raggruppamento degli argomenti che costituiscono il comando da eseguire, come è stato fatto nella seconda invocazione di uplevel.
• In Tcl i comandi restituiscono oltre che una stringa di ritorno, anche un codice intero, che è uno dei seguenti:

  valore	codice	significato	significato della stringa
  0	TCL_OK	Il comando ha completato normalmente l'esecuzione	Risultato del comando
  1	TCL_ERROR	Durante l'esecuzione del comando si è verificato un errore	Messaggio di errore
  2	TCL_RETURN	Il comando ha richiesto che la procedura chiamante termini prematuramente, ritornando a sua volta lo stesso risultato del comando	Risultato del comando
  3	TCL_BREAK	Il comand ha richiesto che il ciclo più interno in cui si trova termini	Stringa vuota
  4	TCL_CONTINUE	Il comando ha richiesto che il cilo più interno in cui si trova salti alla prossima iterazione	Stringa vuota

  Quando il codice di ritorno è diverso da TCL_OK, in mancanza di istruzioni catch(n), le invocazioni di tutti i comandi pendenti terminano restituendo lo stesso codice e stringa di errore. A questo punto l'interprete visualizza un messaggio di errore sul terminale (nel caso di tclsh) oppure in una finestra grafica di notifica (nel caso di wish). Tuttavia se ad un certo punto della catena dei ritorni, si stava eseguendo uno script tramite il comando catch(n), la procedura che contiene questa istruzione catch non viene fatta terminare e può gestire la situazione di errore a piacimento. catch ritorna 0 (TCL_OK) se lo script eseguito sotto il suo controllo non ha prodotto alcun errore, altrimenti ritorna il codice di ritorno eccezionale secondo la tabella precedente. catch inoltre, se viene specificato un secondo parametro, salva la stringa di ritorno prodotta dall'esecuzione dello script nella variabile indicata. Il comando break(n) ritorna il codice TCL_BREAK invece di TCL_OK. Similmente continue(n) ritorna il codice TCL_CONTINUE. Solo i comandi for(n), foreach(n), while(n) e il nostro do intercettano questo tipo di eccezioni, e le gestiscono in modo particolare anziché terminare ripassandole al chiamante: TCL_BREAK causa la terminazione il ciclo, mentre TCL_CONTINUE fa saltare all'iterazione successiva. Dopo aver gestito una eccezione di interruzione ciclo o continuazione ciclo, i comandi di ciclo ritornano TCL_OK, in modo che non vengano interrotti gli altri livelli più elevati di esecuzione.
• Notate che, poiché utilizziamo while, non dobbiamo gestire le interruzioni di tipo TCL_BREAK o TCL_CONTINUE che possono accadere nella seconda chiamata di uplevel, in quanto lo fa già while per noi, mentre dobbiamo gestirle durante la prima esecuzione del body.

Il package control di Tcllib (una collezione di moduli di utilità per Tcl) fornisce un comando do ancora più flessibile, in quanto è possibile scegliere se la condizione deve essere una condizione di continuazione (semantica tipo while) o di terminazione del ciclo (semantica tipo until). Per usarlo basta caricare il package e utilizzare il nome pienamente qualificato del comando o importarlo nel namespace corrente:

package require control

control::do {
  # corpo del ciclo
  # ...
} while {test di continuazione} 

namespace import ::control::*
do {
  # corpo del ciclo
  # ...
} until {test di terminazione}

Vedere inoltre la manpage control(n), sezione LIMITATIONS, per una descrizione di una sottile limitazione legata alla gestione degli errori, di cui soffrono purtroppo tutti i comandi che implementano nuove strutture di controllo direttamente in Tcl, senza far ricorso ad estensioni scritte in C.

« Tcl: Iterazioni: comandi continue e break • Appunti di Tcl/Tk • Tcl: Creazione di nuovi comandi: comandi proc e return »