La curva di von Koch

Nel 1904, il matematico svedese Helge Von Koch, durante la grande crisi delle scienze matematiche, ideò un procedimento infinito che porta alla costruzione di una strana linea matematica, una curva continua in tutto l'intervallo di definizione, ma non derivabile in nessun punto di questo, ossia non dotata di tangente in nessun punto.

Vediamo come costruire delle spezzate che rappresentano approssimazioni via via migliori di questa curva limite, che prende il nome di curva di von Koch o anche linea costiera di Koch.

Si parte da un segmento:

Poi se ne fa una estrusione triangolare, cioè lo si divide in 3 parti uguali e si costruisce un triangolo equilatero di lato pari ad 1/3 della lunghezza del segmento, poggiato sul segmento originale:

Considerate poi i 4 segmenti ottenuti e ripetete il procedimento di estrusione:

E così via ad infinitum...

Segue un programma in Logo per disegnare una spezzata approssimante della curva di von Kock originale, con tutte le linee di costruzione, e una immagine del suo output.

; Logo procedure that draws the von Koch curve
; author web site: http://go.to/ninuzzo

to koch :size
  pd fd :size*3
  pu bk :size lt 120
  pd fd :size
  lt 120 fd :size
  pu lt 120 bk :size

  if :size < 4 [stop]
  koch size/3
  fd :size lt 60
  koch :size/3
  fd :size rt 120
  koch :size/3
  fd :size lt 60
  koch :size/3
  bk :size*2
end

ht cs pu rt 90 bk 150 koch 100

La lunghezza della linea di Koch è infinita. Detta L la lunghezza della linea di partenza originaria, come abbiamo visto al primo passo si divide L in 3 segmenti che saranno quindi lunghi ciascuno L/3. Si può immaginare di ottenere il primo livello di approssimazione sollevando 2 di questi segmenti e aggiungendone un altro, per un totale di 4 segmenti. La linea che si ottiene al primo passo sarà quindi lunga 4/3 L. Similmente ogni passo allunga la linea di 4/3 rispetto al passo precedente.

La lunghezza L_k della linea di Koch è quindi data da un limite elementare, che diverge:

Lk =  lim   (4/3)n L = +∞
     n → +∞

Se si estrude con un quadrato anziché con un triangolo, si ottiene la curva di Koch "quadrata":

; Logo procedure that draws the squared von Koch curve
; author web site: http://go.to/ninuzzo

to koch_square :size
  pd fd :size*3
  pu bk :size lt 90
  pd repeat 3 [fd :size lt 90]
  pu bk :size

  if :size < 4 [stop]
  koch_square :size/3
  fd :size lt 90
  repeat 2 [
    koch_square :size/3
    fd :size rt 90
  ]
  koch_square :size/3
  fd :size lt 90
  koch_square :size/3
  bk :size*2
end

ht cs pu rt 90 bk 150 koch_square 100